Chromatography Forum

Hi again everybody.

I explain exactly what I have to do so you can better understand my problem.
As I wrote before I work with an Agilent HS/GC/MS and I need to optimize a method for the determination of aliphatic hydrocarbons in gasoline range. I'm prompted to quantitate the sum of HC between C5 and C10 as n-hexane.
This is what I've done so far.

In the "Edit Compound" window:

- I defined the n-hexane as a "target compound" and I simply calibrated it using standard solutions;

- I defined the C5-C10 hydrocarbons as a "SemiQuant" compound and I specified for them the "UN" description in the "Compound type" field;

- I put the hexane's identification number at the line labelled "N4" in the HC's "User Defined" page so that the hydrocarbons are quantitate using the hexane's calibration;

- I set "ChemStation" as integrator for the HC and I created an Area Sum event between the C5 and the C10 retention time. I set a very wide range of retention times for this semiQuant compound and, actually, when I quantitate a sample, in the QEdit appears the correct window between pentane and decane.

The problem is that the integration of the area under the hydrocarbons' curve is not reproducible at all and it varies widely with small changes of the start and the end point of integration.

The use of the baseline hold time event does not lead to any improvement.
I've already tried the suggestion to use "FLAT" feature (I read it in a previously post) but I didn't get any results.

So, in the end, my questions are:

1- Is there a way in which I can subtract column bleed area from my range?
2- How can I obtain a reproducible integration of I wide area?

Thank you a lot.

Nina

What ions are you using to quant? From your question I infer you are doing quant. via TIC.
I would suggest you pick ions for each HC you are using, set the time range to omit any internal standards and surrogates.

Hi Bigbear,
I have to integrate the area of all the ions in TIC. In a way I need to use the MS "as a FID".

... am I misunderstanding, you are trying to get the integrator to find the entire area from, say, 5 to 10 minutes, and report it as a single compound? If so, would it be more sensible to get it to integrate the individual peaks you expect to see in this area, and sum them afterwards?

Hi Imh,
yes, I'm trying to integrate the entire area comprised between two known retention times. I can't integrate the individual peaks because I need to quantitate all the alyfatic hydrocarbons in the gasoline range and the reference method requires to integrate the entire "hump" under the baseline in a specific retention time window without any speciation. The Agilent's specialist suggested me to use the "Area Sum" time event in TIC window but, in practice, the integration is not very easy and reproducible.

Don't know if it will work, but under edit compounds you can choose GC signal. This may allow you to do what you want. You may have to specify GC signal in the acquisition method.

Hi Bigbear,
I think yours could be a good idea but in the Acquisition Mode menu I can only choose between SIM, SCAN or both SIM_SCAN mode; I can't find the option "GC signal".
Additionally I need to work with simultaneous SIM_SCAN acquisition because I quantitate hydrocarbons in GRO range using the TIC acquisition and, I quantitate at the same time BTEXS in the SIM acquisition.

Is it possible to select "GC signal" in the Edit Compound window continuing to use the SIM_SCAN acquisition mode?

I believe the "FLAT" option and the ranged integration need the peak type to include "H".

This is WAY easier to do in a macro. Here is a copy of our total petroleum hydrocarbon macro, which breaks the data into hydrocarbon ranges defined by the user from standards. Note that it subtracts a blank chromatogram (we run the solvent as a blank).

AME InitializeVariables
GasStart = 1.13
GasEnd = 3.18
DieselEnd = 7.17
TPHEnd = 8.80
Surr1RT = 2.79
Surr2RT = 5.56
C6Start = 1.15
C8Start = 1.76
C10Start = 2.58
C12Start = 3.25
C16Start = 4.36
C21Start = 5.62
C6 = 0
C6toC8 = 0
C8toC10 = 0
C10toC12 = 0
C12toC16 = 0
C16toC21 = 0
C21toC36 = 0
Pentane = 0
TPHgas = 0
TPHdiesel = 0
TPHOil = 0
RETURN

NAME tpgc
loadmeth "C:\HPCHEM\1\methods\tphgc.m"
open "C:\HPChem\msexe\loadlist.txt" for input as #30
resfile$ = _datapath$+"TPHCalc.txt"
OPEN resfile$ for output as #100
OPEN _datapath$+"TPHspec.txt" for output as #50
SELECTFILE 2,"Select Blank File","*.D",_BlankPath$,_BlankFile$,Fstat
blankfile$ = _BlankPath$+_BlankFile$
While (EOF(30) <> 1)
input #30, newfile$
InitializeVariables
file newfile$
tic
namelength = len(_datafile$)
filename$ = _datafile$[1:namelength-2]
daterun$ = _dateacquired$[1:10]
timerun$ = _dateacquired$[11:20]
sampledil = multiplier
operator$ = _operator$
processfile$ = _datafile$
file blankfile$
tic
sub
integrate
peakvars 0
looper = 1
!Find surrogates
Surr1WindowLow = Surr1RT - 0.15
Surr1WindowHigh = Surr1RT + 0.15
Surr2WindowLow = Surr2RT - 0.15
Surr2WindowHigh = Surr2RT + 0.15
Surr1Area = 0
Surr2Area = 0
while looper <= npeaks
peakvars looper
if ret_time >= Surr1WindowLow and ret_time <= Surr1WindowHigh then
if peak_area > Surr1Area then
Surr1Area = peak_area
endif
endif
if ret_time >= Surr2WindowLow and ret_time <= Surr2WindowHigh then
if peak_area > Surr2Area then
Surr2Area = peak_area
endif
endif
if ret_time > Surr2WindowHigh then
looper = npeaks
endif
looper = looper + 1
endwhile
looper = 1
peakvars 0
while looper <= npeaks
peakvars looper
! Discard peaks that are too early or too late
if ret_time < GasStart then
Pentane = Pentane + peak_area
endif
if ret_time > TPHEnd then
looper = npeaks
endif
! Discard peaks that are too wide
if ret_time >= GasStart and ret_time < GasEnd then
if (end_time - start_time) > 0.075 then
TPHgas = TPHgas
else
TPHgas = TPHgas + peak_area
endif
endif
if ret_time >= GasEnd and ret_time < DieselEnd then
TPHdiesel = TPHdiesel + Peak_area
endif
if ret_time >= DieselEnd and ret_time < TPHEnd then
TPHOil = TPHOil + Peak_area
endif
if ret_time > C6Start and ret_time <=GasStart then
C6 = C6 + peak_area
endif
if ret_time >= GasStart and ret_time <=C8Start then
C6toC8 = C6toC8 + peak_area
endif
if ret_time > C8Start and ret_time <=C10Start then
C8toC10 = C8toC10 + peak_area
endif
if ret_time > C10Start and ret_time <=C12Start then
C10toC12 = C10toC12 + peak_area
endif
if ret_time > C12Start and ret_time <=C16Start then
C12toC16 = C12toC16 + peak_area
endif
if ret_time > C16Start and ret_time <=C21Start then
C16toC21 = C16toC21 + peak_area
endif
if ret_time > C21Start and ret_time <=TPHEnd then
C21toC36 = C21toC36 + peak_area
endif
looper = looper + 1
endwhile
sprint output1$,processfile$,chr$(9),Pentane,chr$(9),TPHgas,chr$(9),TPHdiesel,chr$(9),TPHOil,chr$(9)
sprint output2$,daterun$,chr$(9),timerun$,chr$(9),sampledil,chr$(9),operator$,chr$(9),Surr1Area,chr$(9),Surr2Area
sprint output3$,processfile$,chr$(9),C6,chr$(9),C6toC8,chr$(9),C8toC10,chr$(9)
sprint output4$,C10toC12,chr$(9),C12toC16,chr$(9),C16toC21,chr$(9),C21toC36
print #100,output1$,output2$
print #50,output3$,output4$
endwhile
close #100
close #50
close #30
RETURN